Patarakin: /* Encoding */

2025-10-10T04:30:32Z

Encoding

← Предыдущая версия		Версия от 07:30, 10 октября 2025
Строка 51:		Строка 51:
	Encoding is the process by which users and their data are formatted into a sequence of numbers in the cloud variable "{{^}} leaderboard". First, consider the following lists:		Encoding is the process by which users and their data are formatted into a sequence of numbers in the cloud variable "{{^}} leaderboard". First, consider the following lists:

	~~[[File:Data Compare.png]]~~

	Each user's data is linked to their score. The scores' numerical placement can be accomplished through scripts outside the encoding and decoding. Using this data linkage, the cloud variable encoder can go one-by-one to add each username and score in number format to "{{^}} leaderboard".		Each user's data is linked to their score. The scores' numerical placement can be accomplished through scripts outside the encoding and decoding. Using this data linkage, the cloud variable encoder can go one-by-one to add each username and score in number format to "{{^}} leaderboard".

Patarakin в 04:30, 10 октября 2025

2025-10-10T04:30:06Z

← Предыдущая версия		Версия от 07:30, 10 октября 2025
Строка 1:		Строка 1:
	~~{{Cloud Data}}~~
	~~{{about\|global high scores, although it focuses on encoding and decoding\|strictly encoding and decoding\|Encoding and Decoding Cloud Data}}~~
	With the new [[Cloud Variables\|cloud variable]] feature in [[Scratch 2.0]], '''global high score''' lists can be made within a project. These high score lists, stored inside a cloud [[variable]], can take only seconds to update. This tutorial explains how to code a fully functional global high score list, so users' data can be saved for a particular project.		With the new [[Cloud Variables\|cloud variable]] feature in [[Scratch 2.0]], '''global high score''' lists can be made within a project. These high score lists, stored inside a cloud [[variable]], can take only seconds to update. This tutorial explains how to code a fully functional global high score list, so users' data can be saved for a particular project.
	{{note\|Though this focuses on high scores, this information can also be relevant to any user-saved data.}}		{{note\|Though this focuses on high scores, this information can also be relevant to any user-saved data.}}
Строка 227:		Строка 225:

	[[Category:Scripting Tutorials]]		[[Category:Scripting Tutorials]]

	~~[[fr:Scratch Wiki Accueil/tutos/013 ajouter highscore]]~~

Patarakin: 1 версия импортирована

2022-07-21T08:33:14Z

1 версия импортирована

← Предыдущая версия	Версия от 11:33, 21 июля 2022
(нет различий)

scratch>TemplatesFTW: Automated edit: fixed 1 style guideline

2021-12-29T11:51:31Z

Automated edit: fixed 1 style guideline

Новая страница

{{Cloud Data}}
{{about|global high scores, although it focuses on encoding and decoding|strictly encoding and decoding|Encoding and Decoding Cloud Data}}
With the new [[Cloud Variables|cloud variable]] feature in [[Scratch 2.0]], '''global high score''' lists can be made within a project. These high score lists, stored inside a cloud [[variable]], can take only seconds to update. This tutorial explains how to code a fully functional global high score list, so users' data can be saved for a particular project.
{{note|Though this focuses on high scores, this information can also be relevant to any user-saved data.}}

==Simple high score==
For a simple one that shows the highest score, two variables can be used:
* <sb>(score)</sb>
* <sb>(☁ high score)</sb>

The following script can then be created:

<scratchblocks>
when gf clicked
forever
if <(score) > (☁ high score)> then
set [☁ high score v] to (score)
</scratchblocks>

{{note|This script shows only the highest score, not the username of the person who set it.}}

==Automatically Resetting Scores==
If you want the Global High Score of a game to be reset automatically throughout a period of time so that everyone gets a chance, you can use a script like this one:
<scratchblocks>
when gf clicked
hide variable [☁ Auto Reset v]
forever
if <not <(☁ Auto Reset) = (([floor v] of (days since 2000)::operators)*(number of wanted time in a day::grey))>> then
set [☁ Auto Reset v] to (([floor v] of (days since 2000)::operators)*(number of wanted time in a day::grey))
set [☁ High Score v] to [0]
</scratchblocks>

==Requirements==
Since cloud [[list]]s are rejected, programming this functionality can be quite difficult. Users' data has to be saved in cloud ''variables'', with a limitation: only numbers can be stored. The [[Scratch Team]] currently does not allow letters within cloud variables for security reasons. Therefore, scripts are needed to encode and decode the data into sequences of numbers. This tutorial requires the use of:
* Three lists
** <sb>letter::list reporter</sb>
** <sb>users::list reporter</sb>
** <sb>scores::list reporter</sb>
* Nine variables
** <sb>(score)</sb>
** <sb>(letter#)</sb>
** <sb>(letter detect)</sb>
** <sb>(list item)</sb>
** <sb>(i)</sb>
** <sb>(☁ leaderboard)</sb>
** <sb>(v1)</sb>
** <sb>item::variables reporter</sb>
** <sb>chars::variables reporter</sb>

==Encoding==
Encoding is the process by which users and their data are formatted into a sequence of numbers in the cloud variable "{{^}} leaderboard". First, consider the following lists:

[[File:Data Compare.png]]

Each user's data is linked to their score. The scores' numerical placement can be accomplished through scripts outside the encoding and decoding. Using this data linkage, the cloud variable encoder can go one-by-one to add each username and score in number format to "{{^}} leaderboard".

During the encoding process, each character or number in a list item is represented by a two-digit number. For example, "a" would be the digit "01" and "b" the digit "02". The list "characters" stores as many as 99 characters to encode. If there were 100 or more characters readable by the global high score system, each character would have to be represented by a three-digit value. The order the characters go in this list does not matter; they just have to be consistent throughout the encoding process.

Therefore, each list item (i.e. a user and their score) is separated by "00". Without it, the script could not separate the list items properly, and all the characters would be a large jumble.

After the list is filled out with available computer characters, the cloud variable encoding script can be made. It is a long process encoding the data.

<scratchblocks>
define encode
set [list item v] to [1]
set [v1 v] to []
repeat (length of [users v])
set [letter detect v] to [1]
set [letter# v] to [1]
repeat (length of (item (list item) of [users v]))
set [letter detect v] to [1]
repeat until <(letter (letter#) of (item (list item) of [users v])) = (item (letter detect) of [letter v])>
change [letter detect v] by (1)
end
if <(letter detect) < [10]> then
set [v1 v] to (join (v1) (join [0] (letter detect)))
else
set [v1 v] to (join (v1) (letter detect))
end
change [letter# v] by (1)
end
set [v1 v] to (join (v1) [00])
set [letter detect v] to [1]
set [letter# v] to [1]
repeat (length of (item (list item) of [scores v]))
set [letter detect v] to [1]
repeat until <(letter (letter#) of (item (list item) of [scores v])) = (item (letter detect) of [letter v])>
change [letter detect v] by (1)
end
if <(letter detect) < [10]> then
set [v1 v] to (join (v1) (join [0] (letter detect)))
else
set [v1 v] to (join (v1) (letter detect))
end
change [letter# v] by (1)
end
set [v1 v] to (join (v1) [00])
change [list item v] by (1)
end
set [☁ leaderboard v] to (v1)
</scratchblocks>

==Decoding==
Decoding is the process by which the numerically encoded data is decoded, or taken out of number format and compiled into the two lists again. Decoding checks for the "00" placed between list items during the encoding to determine when to iterate to the next list item. After the process is complete, the lists will be arranged in the manner prior to the encoding.

<scratchblocks>
define decode
set [letter# v] to [0]
set [letter detect v] to [1]
delete all of [users v]
delete all of [scores v]
add [] to [users v]
add [] to [scores v]
repeat until <(letter#) > ((length of (☁ leaderboard)) - (1))>
repeat until <(join (letter ((letter#) + (1)) of (☁ leaderboard)) (letter ((letter#) + (2)) of (☁ leaderboard))) = [00]>
set [letter detect v] to [1]
repeat until <(letter detect) = (join (letter ((letter#) + (1)) of (☁ leaderboard)) (letter ((letter#) + (2)) of (☁ leaderboard)))>
change [letter detect v] by (1)
if <(letter detect) < [10]> then
set [letter detect v] to (join [0] (letter detect))
end
end
if <(letter (1) of (letter detect)) = [0]> then
set [letter detect v] to (letter (2) of (letter detect))
end
replace item (last v) of [users v] with (join (item (last v) of [users v]) (item (letter detect) of [letter v]))
change [letter# v] by (2)
end
change [letter# v] by (2)
repeat until <(join (letter ((letter#) + (1)) of (☁ leaderboard)) (letter ((letter#) + (2)) of (☁ leaderboard))) = [00]>
set [letter detect v] to [1]
repeat until <(letter detect) = (join (letter ((letter#) + (1)) of (☁ leaderboard)) (letter ((letter#) + (2)) of (☁ leaderboard)))>
change [letter detect v] by (1)
end
replace item (last v) of [scores v] with (join (item (last v) of [scores v]) (item (letter detect) of [letter v]))
change [letter# v] by (2)
end
add [] to [users v]
add [] to [scores v]
change [letter# v] by (2)
end
delete (length of [users v]) of [users v]
delete (length of [users v]) of [scores v]
</scratchblocks>

==Adding and Replacing Scores==
When adding and replacing the scores in the lists, a variable is needed to iterate through the
list to the correct numerical placement. If the high score leaderboards (consisting of the list "users" and "scores") does not contain the user running the project, their username and score will be added to the lists at the beginning of a project. The following script can replicate this situation:
<scratchblocks>
when gf clicked
delete all of [letter v]
set [chars v] to [� !"#$%&'()*+,-./:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`abcdefghijklmnopqrstuvwxyz{|}~0123456789
set [item v] to (1)
repeat (length of (chars::variables))
add (letter (item) of (chars::variables)) to [letter v]
change [item v] by [1]
end
decode::custom
if <<not <(username) = []>>and<not<[users v] contains (username)?>>> then //checks if the user is logged in to Scratch and not in the leaderboard
add (username) to [users v]
add [0] to [scores v] //in which "0" is the initial score
encode::custom
end
</scratchblocks>
The example above shows how to add a completely new user to the leaderboards. What if the user is already in the leaderboards but had reached a higher score? To replace a user's current high score with a new one, the current high score must first be deleted. Then, the new high score can be added to the list by iterating down the list with a variable until the score is greater than the one being analyzed. The following script performs this function:
<scratchblocks>
define change leaderboard
decode::custom
if <[users v] contains (username)> then //checks if the user has been added to the leaderboard already
set [i v] to [1] //begin with the first list item
repeat until <(item (i) of [users v]) = (username)> //the deletion process
change [i v] by (1)
end
delete (i) of [users v]
delete (i) of [scores v]
set [i v] to [1]
repeat until <<(i) > (length of [scores v])> or <(score) > (item (i) of [scores v])>> //the variable "score" is the latest score of the user
change [i v] by (1) //it will end at the proper list location
end
insert (username) at (i) of [users v]
insert (score) at (i) of [scores v]
encode::custom
</scratchblocks>
Then, use this:
<scratchblocks>
when gf clicked
delete all of [letter v]
set [chars v] to [� !"#$%&'()*+,-./:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`abcdefghijklmnopqrstuvwxyz{|}~0123456789
set [item v] to (1)
repeat (length of(chars::variables))
add (letter (item) of (chars::variables)) to [letter v]
change [item v] by [1]
end
decode::custom
if <<not <(username) = []>>and<not<[users v] contains (username)?>>> then //checks if the user is logged in to Scratch and not in the leaderboard
add (username) to [users v]
add [0] to [scores v] //in which "0" is the initial score
encode::custom
end
forever
change leaderboard::custom
end
</scratchblocks>

==Avoiding Interference==
When encoding (saving) the data stored in the lists, the cloud [[variable]]s can take about two seconds to update. If multiple people happen to be encoding at the same time, glitches could occur which cause the data to become broken, changed, or deleted. Also, any disrupted data in the encoder can sometimes cause an [[wikipedia:Infinite loop|infinite loop]] in the decoder, though scripts can be used to prevent that. These issues are particularly more likely to occur on a very popular project with tons of data to be encoded. To prevent any such encoding interference from destroying a leaderboard, saving back-ups of the lists often can be very useful.

A script to prevent that can be made but takes time if it is to have a low margin for error. Create a custom block called 'wait and encode'. Also, create another cloud variable.

<sb>(☁ queue)</sb>

<scratchblocks>
define wait and encode
repeat until <(☁ queue) = (0)>
wait until <(☁ queue) = [0]>
wait (pick random (1) to (5)) secs
end
set [☁ queue v] to (1)
encode::custom
set [☁ queue v] to (0)
</scratchblocks>

The higher the second bound of the random wait, the less margin for error there is. What can happen is two computers can still try to encode simultaneously but there is less chance this way.

[[Category:Scripting Tutorials]]

[[fr:Scratch Wiki Accueil/tutos/013 ajouter highscore]]

Global High Scores - История изменений

Patarakin: /* Encoding */

Patarakin в 04:30, 10 октября 2025

Patarakin: 1 версия импортирована

scratch>TemplatesFTW: Automated edit: fixed 1 style guideline